Réduire son disque dur sur XP

Système d'exploitation Microsoft Windows
1

SAlut à tous,
Je souhaiterais savoir comment on peut réduire sensiblement la taille de Windows XP par exemple en virant les updates une fois installées ou msn dont je ne me sert pas (mais elles sont où?)

Merci d’avance
ptitced

2

Si tu cherche de la place a ce point …, dans l’explorateur windows, options des dossiers, Affichage et cocher la case Afficher les fichiers et dossiers cachés, ensuite dans le dossier Windows tu verra des dossiers compressés avec un $ devant (en bleu)…tu peut les supprimer mais attention après tu ne pourra plus désinstaller une mise à jour dans le Panneau de configuration-Ajout/Supprimer des programmes …si jamais une mise à jour pose des problèmes où autre. Pour messenger je pense que tu veut parler de Windows Messenger?

Bon, ila plus simple et plus propre comme manipulation, cependant un où deux dossiers vont rester présent sur la machine (n’essai pas comprendre pq) :wink: , ouvre le Bloc-notes et coller-ci :

If MsgBox("This program will now remove uninstall folders.", _
    vbOkCancel, "Uninstall Remover") = vbOk Then

Set oShell = CreateObject("WScript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
sWinDir = oFSO.GetSpecialFolder(0)
Set oFolder = oFSO.GetFolder(sWinDir)
Set oDictionary = CreateObject("Scripting.Dictionary")

For Each oSubFolder In oFolder.SubFolders

  sFolderName = LCase(oSubFolder.Name)
  sFolderPath = LCase(oSubFolder.Path)

  If     Left(sFolderName, 13) = "$ntuninstallq" _
      Or Left(sFolderName, 14) = "$ntuninstallkb" Then

    ' Get the update name for the registry delete:

    sUpdateName = Mid(sFolderName, 13, Len(sFolderName) - 13)

    ' Never delete folders/files while enumerating a file/folder collection.
    ' Adds them to a dictionary object for later handling instead:

    oDictionary.Add sUpdateName, sFolderPath

  End If
Next

sDeleted = ""
For Each sUpdateName In oDictionary.Keys

  sDeleted = sDeleted & vbCrLf & sUpdateName
  sFolderPath = oDictionary.Item(sUpdateName)

  On Error Resume Next

  ' Remove entry in Add/Remove Programs:

  oShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows\" _
      & "CurrentVersion\Uninstall\" & sUpdateName & "\"
  On Error Goto 0

  ' Delete the unisntall folder:

  oShell.Run "%Comspec% /C RD /S /Q " _
      & Chr(34) & sFolderPath & Chr(34), 0, True
Next

If sDeleted <> "" Then
  MsgBox "The uninstall data for the following updates has been removed:" _
       & vbCrLf & UCase(sDeleted)
Else
  MsgBox "No update uninstall data found."
End If

End If

enregistrer avec extension .vbs ex: pticed.vbs et l’exécuter(si tu a norton faudra le désactiver, soit le blocage de script dans celui-ci) et pour messenger ont va faire pareil, ouvrir le Bloc-notes et coller la suite :

Option Explicit
On Error Resume Next

'Dimension variables
Dim WSHShell, MyBox, p1, q1, rcmd
Dim jobfunc

'Set the Windows Script Host Shell and assign values to variables
Set WSHShell = WScript.CreateObject("WScript.Shell")
p1 = "HKEY_LOCAL_MACHINE\Software\Microsoft\Outlook Express\Hide Messenger"
q1 = 2
rcmd = "RunDll32 advpack.dll,LaunchINFSection %windir%\inf\msmsgs.inf,BLC.Remove"

'Create or change the Hide Messenger value
WSHShell.RegWrite p1, q1

'Run the uninstall command
WshShell.Run(rcmd)

enregistrer avec extension .vbs ex: ptimessenger.vbs et l’exécuter
voilà, c’est plus propre ainsi que à la barbare :wink:

3

Ca libère combien de Mo cet manipulation?

4

Merci pour ton coup de main, en fait je sais pas si j’ai un problème mais mon windows XP avec drivers et office me font un total de 14.6 Go… sue un disque dur de 15Go
Donc oui besoin de place…

5

essai de liberer des points de restauration(si tu fais usage de la restauration système) et laisser le plus recent, vider le dossier(le contenu) Prefetch, nettoyage du disque, fichiers temporaires etc

tien un logiciel sympa ccleaner.com
:slight_smile: